(*
 * LANGUAGE    : ANS Forth
 * PROJECT     : Forth Environments
 * DESCRIPTION : Julia fractal of c sin(z)
 * CATEGORY    : Graphic example
 * AUTHOR      : Marcel Hendrix 
 * LAST CHANGE : Tuesday, December 30, 2003 9:09 PM, Marcel Hendrix 
 *)



        NEEDS -miscutil
	NEEDS -graphics

        REVISION -julsin "ÄÄÄ Julia c sin(z)      Version 1.00 ÄÄÄ"

	PRIVATES


DOC
(*
 Julia fractal of c sin(z)
*)
ENDDOC

-- Parameters 
 0.6e       FVALUE Aa
 0.6e       FVALUE Bb
 PI 1.5e F* FVALUE delH
 4e 	    FVALUE delV
   9         VALUE amp

-- Globals
       0. DVALUE @XY    PRIVATE

: COLORIZE ( ix -- ) 
		3 * palette + 
		C@+ amp * >S
		C@+ amp * >< S> OR >S
		C@  amp * #16 LSHIFT S> OR >S
		@XY S> SET-MDOT ;

: INNERLOOP ( x y -- ) 
		2DUP TO @XY UNSCALE? DROP FLOCALS| yy xx |
		0e 0e 0e 0e 0e 0e 0e 0e FLOCALS| x2 y2 x1 y1  ch sh cs ss |
		#50  1 DO  yy FABS 20e
			    F> IF  I COLORIZE  LEAVE  ENDIF
			   yy 	      FEXP 
			   yy FNEGATE FEXP ( uu vv )
			   F2DUP F+ F2/ TO ch  
			         F- F2/ TO sh
			   xx FSINCOS   TO cs  		 
			   		TO ss
			   ss ch F*     TO x1  
			   cs sh F*     TO y1
			   Aa x1 F*  Bb y1 F* F- TO x2
			   Aa y1 F*  Bb x1 F* F+ TO y2
			   xx x2 F- FSQR  yy y2 F- FSQR F+ 1e-6 
			    F< IF  I COLORIZE  LEAVE  ENDIF
			   x2 TO xx  y2 TO yy
		     LOOP ;P

: COMPUTE	TEXTMODE? DUP >R IF GRAPHICS ENDIF  
		0 0 Xmax Ymax  0e 0e delH delV SET-GWINDOW GCLEAR 
		#50 RANDOMPALETTE
		RESET-MDOTS
		  Xmax 0 ?DO  Ymax 0 ?DO  J I INNERLOOP  LOOP  LOOP
		FLUSH-MDOTS
		R> IF  TEXT  ENDIF ;

:ABOUT		CR ." Type COMPUTE for a Julia fractal."
		CR
		CR ."  1.4e TO delH  1.4e TO delV -- zoom picture "
		CR ."  9 TO amp  COMPUTE          -- influence contrast " 
		CR
		CR ." Example parameters: "
		CR ." -1.754878e TO Aa  0e        TO Bb COMPUTE "
		CR ." -1.543689e TO Aa  0e        TO Bb COMPUTE " 
		CR ." 5e 4e F/   TO Aa  0e        TO Bb COMPUTE " 
		CR ." -1e        TO Aa  0e        TO Bb COMPUTE " 
		CR ." -0.75e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0e        TO Bb COMPUTE " 
		CR ."  0.3e      TO Aa  0e        TO Bb COMPUTE "
		CR ." -0.122561e TO Aa  0.744862e TO Bb COMPUTE "
		CR ." -0.101096e TO Aa  0.956287e TO Bb COMPUTE "
		CR ."  0.11e     TO Aa  0.67e     TO Bb COMPUTE " 
		CR ."  0.25e     TO Aa  0.25e     TO Bb COMPUTE "
		CR ." -0.318472e TO Aa  0.041257e TO Bb COMPUTE " ;

                .ABOUT -julsin CR
		DEPRIVE

                              (* End of Source *)